Inoffizielles deutsches Xbase-Forum

Code: Alles auswählen

#include "ot4xb.ch"
// ---------------------------------------------------------------------------
proc main()
local nDeviceId   := 9  // change this value for your device ID
local hLineApp    := 0
local nDevCnt     := 0
local nVersion    := 0x20000
local aLineParams := {24,0,0,2,0,0}
local result      := @tapi32:lineInitializeExA(@hLineApp,AppInstance(),0,;
                     "Test",@nDevCnt,@nVersion,@aLineParams)
local hLine       := 0         
local conCargo    := 0 // _var2con( XbaseArrayCodeblockOrObjectVariable )

if result == 0
   ? "lineInitializeEx() -> OK"
   Thread():New():Start({|| LineEventsProc( aLineParams[5] , hLineApp)} )
   result := @tapi32:lineOpenA(hLineApp,nDeviceId,@hLine,;
                               nVersion,0,conCargo,2,0x12,0)

   if result == 0
      ? "lineOpen() -> OK"
      while inkey(0) != 27 ; end
      @tapi32:lineClose( hLine )
   else
      ? "lineOpen() -> FAIL"
   end               
   @tapi32:lineShutdown( hLineApp )
else
   ? "lineInitializeEx() -> FAIL"
end
if conCargo != 0 ; _conRelease( conCargo ) ; end   
? "Press a key to exit .... "
inkey(0)
return
// ---------------------------------------------------------------------------
function LineEventsProc(hEvent,hLineApp)
local aMsg := AFill(Array(6),0)
? "------  LineEventsProc() ENTER ----- "
while( @kernel32:WaitForSingleObject(hEvent,-1) != -1 )
   while( @tapi32:lineGetMessage(hLineApp,@aMsg,0) == 0 )
      ? "------  LineEventsProc() ----- "
      ? cPrintf( "hDevice     : 0x%08X" , aMsg[1] )
      ? cPrintf( "dwMessageId : 0x%08X" , aMsg[2] )
      ?          "cargo       : " , _con2var( aMsg[3] )
      ? cPrintf( "dwParam1    : 0x%08X" , aMsg[4] )
      ? cPrintf( "dwParam2    : 0x%08X" , aMsg[5] )
      ? cPrintf( "dwParam3    : 0x%08X" , aMsg[6] )
      ? "------------------------------ "
   end
end
? "------  LineEventsProc() EXIT ----- "
return NIL
// ---------------------------------------------------------------------------