Inoffizielles deutsches Xbase-Forum

Code: Alles auswählen

#include "ot4xb.ch"
// ---------------------------------------------------------------------------
// ---------------------------------------------------------------------------
DLL	AdsDLL	IMPORT AdsPortOpen AS INT32

// ---------------------------------------------------------------------------
DLL	AdsDLL	IMPORT AdsGetLocalAddress AS INT32;
				PARAM pAddr AS LPSTR

// ---------------------------------------------------------------------------

DLL	AdsDLL	IMPORT AdsSyncReadWriteReq AS INT32;
  				PARAM pAddr		AS LPSTR,;
				PARAM nIndexGroup	AS INT32,;
				PARAM nIndexOffset	AS INT32,;
				PARAM nReadLength	AS INT32,;
				PARAM pReadData		AS LPSTR,;
				PARAM nWriteLength	AS INT32,;
				PARAM pWriteData        AS LPSTR
// ---------------------------------------------------------------------------

DLL	AdsDLL	IMPORT AdsSyncReadReq AS INT32;
  				PARAM pAddr		AS LPSTR,;
				PARAM nIndexGroup	AS INT32,;
				PARAM nIndexOffset	AS INT32,;
				PARAM nReadLength	AS INT32,;
				PARAM pReadData		AS LPSTR
// ---------------------------------------------------------------------------
DLL	AdsDLL	IMPORT AdsSyncWriteReq AS INT32;
  				PARAM pAddr		AS LPSTR,;
				PARAM nIndexGroup	AS INT32,;
				PARAM nIndexOffset	AS INT32,;
				PARAM nWriteLength	AS INT32,;
				PARAM pWriteData	AS LPSTR
// ---------------------------------------------------------------------------
// ---------------------------------------------------------------------------
DLL	AdsDLL	IMPORT AdsPortClose AS INT32



procedure main

local   nErr,nPort
local	Addr := space(10)
local	ZielVar:= space(200)
local	sVar
local   AnzLesen
local	i,y
local   nHandl:= space(4)



local aWerte[100],bWerte[100]

for i:=1 to 100
   aWerte[i] := 0
   bWerte[i] := 0
next i

nPort = AdsPortOpen()
//nErr = AdsGetLocalAddress(@Addr)
/*     Hintergrundinformation zur Kommunikation mit ADS Funktionen:

	In unserem Fall wird von einem CP7701 (Touch-Panel) aus einer CX9000 Variableninhalte gelesen.

	Um eine Kommunikation zu ermöglichen mussten beide in den gleichen IP-Rahmen gelegt werden
		- CP7701 (mit zwei Schnittstellen) ==> 192.168.5.204 (1. Schnittstelle) und 192.168.5.205 (2.Schnittstelle)
			  ==> mittels Netzwerkeinstellungen
			- Route hinzugefügt.  Im CP 7701 wurde der Name vom CX9000 + AMS + IP hinzugefügt.
			  ==> EXPLORER ==> Harddisk ==> System ==> TcAmsRemoteMgr
				Name: CX_053553		AMS 5.5.53.83.1.1 IP 192.168.5.203   (CX Prüfanlage)

		- CX9000 (Prüfanlage)  ==> IP 192.168.5.203  (mit Hilfe von CERHOST)
			==> mittesl Netzwerkeinstellungen
			- Route hinzufügen . IM CX9000 wurde der Name vom CP7701 + AMS + IP hinzugefügt.
			==> CERHOST ==> EXPLORER ==> Harddisk ==> System ==> TcAmsRemoteMgr
				Name: CP_076018		AMS 5.7.96.24.1.1	IP 192.168.5.205 (2. Schnittstelle verwendet)
*/

/*  Mit der Funktion AdsSyncReadWriteReq kann aus einer x-beliebigen Steuerung durch Angabe der AMS-Ned-Id und Port_nr
    eine Variable bzw. ein Array gelesen werden.


	Erkenntnis:

	nErr = AdsSyncReadWriteReq(@Addr, 0xF004, 0, AnzLesen, @ZielVar, len(sVar), @sVar)
	Will man nur Daten aus Beckhoff lesen, reicht die funktion AdsSyncReadWrite mit Indexgroup F004
	d.h. man kann Variableninhalte aus der Steuerung lesen per Angabe des Vriablennamens

	Will man Daten in die Beckhoffsteuerung schreiben, und dies auch per Name, erfolgt dies in zwei Schritten
	1. nErr = AdsSyncReadWriteReq(@Addr, 0xF003, 0, 4, @nHandl, len(sVar), @sVar)
	   Handl zu dem Variablennamen aus Steuerung lesen ==> Wichtig Indexgroup F003
	2. nErr = AdsSyncWriteReq(@Addr, 0xF005, @nHandl, 2, @sVar)
	   Mittels Handl Variablenwert schreiben  ==> Wichtig Indexgroup F005

	Mit dieser Methode könnte man auch Daten lesen
	1. nErr = AdsSyncReadWriteReq(@Addr, 0xF003, 0, 4, @nHandl, len(sVar), @sVar)
	   Handl zu dem Variablennamen aus Steuerung lesen ==> Wichtig Indexgroup F003
	2. nErr = AdsSyncReadReq(@Addr, 0xF005, @nHandl, AnzLesen, @ZielVar)
	   Mittels Handl Variablenwert lesen ==> Wichtig Indexgroup F005

*/

/*********************************************************************************************/
// AMS NET ID zusammenstellen  z.B 5.5.53.83.1.1
Addr := stuff(Addr,1,1,chr(5))
Addr := stuff(Addr,2,1,chr(5))
Addr := stuff(Addr,3,1,chr(53))
Addr := stuff(Addr,4,1,chr(83))
Addr := stuff(Addr,5,1,chr(1))
Addr := stuff(Addr,6,1,chr(1))
// Portadresse zusammenstellen  z.B 801
Addr := stuff(Addr,7,2,u2bin(801))
sVar := ".test_com"
AnzLesen := 20		// Anzahl Lesen in Bytes d.h. Word ==> *2  DWord *4
nErr = AdsSyncReadWriteReq(@Addr, 0xF004, 0, AnzLesen, @ZielVar, len(sVar), @sVar)
//********************************************************************************************/

for i:=1 to 10
    y := (I*2) - 1
    bWerte[i] := bin2u(substr(ZielVar,y,2))
next i

ZielVar := Space(200)

sVar := ".test_com"
nErr = AdsSyncReadWriteReq(@Addr, 0xF003, 0, 4, @nHandl, len(sVar), @sVar)

sVar := u2bin(125)
nErr = AdsSyncWriteReq(@Addr, 0xF005, @nHandl, 2, @sVar)

nErr = AdsSyncReadReq(@Addr, 0xF005, @nHandl, AnzLesen, @ZielVar)

for i:=1 to 10
    y := (I*2) - 1
    bWerte[i] := bin2u(substr(ZielVar,y,2))
next i


nErr :=AdsPortClose()

return